SPARQL

新宮町のSPARQL Endpoint
クエリ
出力形式


LODとSPARQL

  Linked Open Data (LOD) は、Resource Description Framework (RDF) に則り、主語、述語、目的語の3要素(Triple)でリソースを表現したLinked Dataをオープンデータとして公開したものです。URI※1またはIRI※2を用いて各リソースをリンクすることができ、大規模な知識データベースを構築できます。LODは、データのウェブ(Web of data)、またはセマンティック・ウェブ(Semantic Web)と呼ばれるウェブの基盤技術として期待されており、また、オープンガバメントの推進に貢献する技術として近年注目を集めています。

  SPARQL Protocol and RDF Query Language (SPARQL) は、RDFで記述されたデータのリソースを検索するためのクエリ言語です。本サイトでは、OpenLink Softwareが提供するOpenLink Virtuosoを用いたSPARQL Endpointを設置しています。

※1 Uniform Resource Identifier (URI),※2 Internationalized Resource Identifier (IRI)

観光語彙基盤

  本サイトで提供しているLODは、観光語彙基盤に基づいて作成しています。観光語彙基盤は、観光分野のリソースを表現するために開発された述語セットであり、各リソースのリンク関係を構築しやすいように設計されています。

クエリの例

沖田中央公園のリソースを検索

prefix tour:<http://www.tourism.property/#>

select distinct * where {
    <http://www.tanoshingu.org/沖田中央公園>
    ?p ?o.
}

実行結果はこちら

沖田中央公園の住所を検索

prefix tour:<http://www.tourism.property/#>

select distinct ?address where {
    <http://www.tanoshingu.org/沖田中央公園>
    tour:住所 ?address.
}

実行結果はこちら

沖田中央公園の英語表記を検索

prefix tour:<http://www.tourism.property/#>

select distinct ?name where {
    <http://www.tanoshingu.org/沖田中央公園>
    tour:名称 ?name.
    filter(lang(?name) = "en")
}

実行結果はこちら

新宮町の人口を検索

prefix tour:<http://www.tourism.property/#>

select distinct ?population where {
    ?s
    tour:名称 "新宮町"@ja;
    tour:人口 ?population.
}

実行結果はこちら

若宮神社の緯度・経度を検索

prefix tour:<http://www.tourism.property/#>

select distinct ?latitude ?longitude where {
    ?s
    tour:名称 "若宮神社"@ja;
    tour:緯度 ?latitude;
    tour:経度 ?longitude.
}

実行結果はこちら

丸山食堂の周辺にある神社を検索

prefix tour:<http://www.tourism.property/#>

select distinct ?spot where {
    {
        select ?latitudeA ?longitudeA where {
            ?s
            tour:緯度 ?latitudeA;
            tour:経度 ?longitudeA;
            tour:名称 "丸山食堂"@ja.
        }
    }

    ?s
    tour:緯度 ?latitudeB;
    tour:経度 ?longitudeB;
    tour:キーワード <http://ja.dbpedia.org/resource/神社>;
    tour:名称 ?spot.

    filter((?latitudeA - 0.009) <= ?latitudeB && ?latitudeB <= (?latitudeA + 0.009))
    filter((?longitudeA - 0.009) <= ?longitudeB && ?longitudeB <= (?longitudeA + 0.009))
    filter(lang(?spot) = "ja")
}

実行結果はこちら

漁業の文字列を含む概要を検索

prefix tour:<http://www.tourism.property/#>

select distinct ?name ?abstract where {
    ?s
    tour:概要 ?abstract;
    tour:名称 ?name.
    filter(regex(?abstract, "漁業"))
    filter(lang(?name) = "ja")
}

実行結果はこちら

沖田中央公園のポイント(要点)を検索

prefix tour:<http://www.tourism.property/#>

select distinct ?headline ?abstract where {
    {
        select distinct ?point where {
            ?s
            tour:要点 ?point;
            tour:名称 "沖田中央公園"@ja.
        }
    }

    ?point
    tour:名称 ?headline;
    tour:概要 ?abstract.
}

実行結果はこちら

ダウンロード

たのしんぐうプロジェクトは、本データの利用に起因する如何なる損失や損害について責任を負いません。

■ 名称    :新宮町LOD

■ ライセンス :CC BY

■ 更新日   :2017年1月15日(日)17時00分

■ ダウンロード:tanoshingu20170115.ttl

■ 備考    :本データは、手動で作成されたものです。

==========================================

■ 名称    :新宮町LOD

■ ライセンス :CC BY

■ 更新日   :2017年6月8日(木)17時00分

■ ダウンロード:tanoshingu20170608.ttl

■ 備考    :本データは、本たのしんぐうの各ページから自動的に生成されたものです。

外部リンク

3 responses to “SPARQL”

  1. 名無し より:

    SPARQLのクエリって難しいですね。よく分からないです。。。

  2. もっちー より:

    キーワード検索をするためにはどうしたらいいですか?

    • tanoshingu より:

      以下のようにクエリを作成することでキーワード検索が可能です。
      なお、”<“と”>”を全角で記述しておりますので、お気を付けください。

      ———————————————

      prefix tour:<http://www.tourism.property/#>;

      select distinct * where {
      ?s
      tour:キーワード <http://ja.dbpedia.org/resource/自然>,
      <http://ja.dbpedia.org/resource/観光>.
      }

      ———————————————

      よろしくお願い致します。

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です